<- InputBox (vba-vbs) Renommer un disque (vbs) ->

Afficher les informations des disques (VBScript)

Le script suivant affiche une boîte de message pour chaque lecteur, avec quelques-unes de ses propriétés.

dim objFSO, colDrives, objDrive, aff, tempaff 
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set colDrives = objFSO.Drives 
For Each objDrive in colDrives
	if (objDrive.IsReady = true) then
		aff = "LETTRE DU DISQUE : " & objDrive.DriveLetter & vbcrlf
		aff = aff & "NOM DU DISQUE : " & objDrive.VolumeName & vbcrlf
		aff = aff & "NUMERO DE SERIE : " & objDrive.SerialNumber & vbcrlf 
		aff = aff & "TYPE DE DISQUE : " & objDrive.DriveType & vbcrlf
		aff = aff & "SYSTEME DE FICHIERS : " & objDrive.FileSystem & vbcrlf
		aff = aff & "PATH : " & objDrive.Path & vbcrlf
		aff = aff & "DOSSIER RACINE : " & objDrive.RootFolder & vbcrlf
		aff = aff & "ESPACE TOTAL : " & objDrive.TotalSize & vbcrlf
		aff = aff & "ESPACE DISPONIBLE : " & objDrive.AvailableSpace & vbcrlf
		if (objDrive.ShareName <> "") then
			aff = aff & vbcrlf & "NOM DE PARTAGE : " & objDrive.ShareName
		end if
		MsgBox aff, vbInformation, "DiskInfo(brol)"
	else
		Wscript.Echo "DISQUE " & objDrive.DriveLetter & " NON PRET"
	end if 
Next
Wscript.Echo colDrives.count & " DISQUES AFFICHES"

Procédure pas à pas

La procédure présentée ici permet de tester tous les objets de la collection drive (tous les lecteurs).

For Each objDrive in colDrives

.../
suite du code
/...

Ensuite, nous devons tester la disponibilité du lecteur de disquettes et des lecteurs CD, etc.

Si le lecteur n'est pas disponible, un message est généré.

if (objDrive.IsReady = true) then

.../
suite du code
.../

else

Wscript.Echo "DISQUE " & objDrive.DriveLetter & " NON PRET"

end if

A présent, nous allons générer l'affichage des propriétés des disques qui sont disponibles. Pour cela, nous pouvons ajouter à chaque fois les données dans la variable aff que nous avons déclaré plus haut.

Nous pouvons remarquer l'emploi de vbcrlf, qui correspond à un retour chariot, pour une meilleure présentation.

aff = "LETTRE DU DISQUE : " & objDrive.DriveLetter & vbcrlf
aff = aff & "NOM DU DISQUE : " & objDrive.VolumeName & vbcrlf
aff = aff & "NUMERO DE SERIE : " & objDrive.SerialNumber & vbcrlf
aff = aff & "TYPE DE DISQUE : " & objDrive.DriveType & vbcrlf
aff = aff & "SYSTEME DE FICHIERS : " & objDrive.FileSystem & vbcrlf
aff = aff & "PATH : " & objDrive.Path & vbcrlf
aff = aff & "DOSSIER RACINE : " & objDrive.RootFolder & vbcrlf
aff = aff & "ESPACE TOTAL : " & objDrive.TotalSize & vbcrlf
aff = aff & "ESPACE DISPONIBLE : " & objDrive.AvailableSpace & vbcrlf

Nous pouvons en plus tester si le lecteur est un lecteur partagé. Dans le cas où il est partagé, nous allons afficher son nom de partage.

if (objDrive.ShareName <> "") then

aff = aff & vbcrlf & "NOM DE PARTAGE : " & objDrive.ShareName

end if

Il ne nous reste plus qu'à afficher le résultat de la variable.

Wscript.Echo aff

A la fin, nous pouvons afficher le nombre de disques trouvés, pour déclarer que le traitement est terminé.

Wscript.Echo colDrives.count & " DISQUES AFFICHES"

Variantes

Voici un autre exemple, qui affiche le résultat sur une seule boîte (je n'affiche pas la totalité de l'image pour gagner un peu de place ;-) ).

Cela peut poser un problème chez ceux qui utilisent la totalité des lettres de l'alphabet pour leurs connecteurs réseaux...

Cet exemple présente de plus la particularité de faire appel à une fonction qui associera un nom au type de disque, au lieu d'une valeur.

Sub DiskInfo
	Dim objFSO, colDrives, objDrive, aff, tempaff 
	Set objFSO = CreateObject("Scripting.FileSystemObject")
	Set colDrives = objFSO.Drives 
	For Each objDrive in colDrives	
		if (objDrive.IsReady = true) then	
			aff = aff & vbcrlf & vbcrlf & "LETTRE DU DISQUE : " & objDrive.DriveLetter & vbcrlf
			aff = aff & "NOM DU DISQUE : " & objDrive.VolumeName & vbcrlf
			aff = aff & "NUMERO DE SERIE : " & objDrive.SerialNumber & vbcrlf
			aff = aff & "TYPE DE DISQUE : " & DiskType (objDrive.DriveType) & vbcrlf
			aff = aff & "SYSTEME DE FICHIERS : " & objDrive.FileSystem & vbcrlf
			aff = aff & "PATH : " & objDrive.Path & vbcrlf
			aff = aff & "DOSSIER RACINE : " & objDrive.RootFolder & vbcrlf
			aff = aff & "ESPACE TOTAL : " & objDrive.TotalSize & vbcrlf
			aff = aff & "ESPACE DISPONIBLE : " & objDrive.AvailableSpace & vbcrlf
			if (objDrive.ShareName <> "") then		
				aff = aff & vbcrlf & "NOM DE PARTAGE : " & objDrive.ShareName	
			end if	
		else	
			aff = aff& vbcrlf& vbcrlf & "DISQUE " & objDrive.DriveLetter & " NON PRET" & vbcrlf
			aff = aff & "TYPE DE DISQUE : " & DiskType (objDrive.DriveType)	
		end if 	
	Next
	Wscript.Echo colDrives.count & " DISQUES AFFICHES" & vbcrlf & aff
End Sub
Function DiskType (ByVal dType)
	Dim affType
	Select Case dType
		Case 0 : affType = "INCONNU"
		Case 1 : affType = "DISQUE AMOVIBLE"
		Case 2 : affType = "FIXE"
		Case 3 : affType = "DISTANT"
		Case 4 : affType = "CD-ROM"
		Case 5 : affType = "RAMDISK"
	End Select
	DiskType = affType
End Function
DiskInfo

<- InputBox (vba-vbs) Renommer un disque (vbs) ->

Nuage de mots clés

31 mots clés dont 0 définis manuellement (plus d'information...).

Avertissement

Cette page ne possède pas encore de mots clés manuels, ceci est donc un exemple automatique (les niveaux de pertinence sont fictifs, mais les liens sont valables). Pour tester le nuage avec une page qui contient des mots définis manuellement, vous pouvez cliquer ici.

Structure du document

Nuage de mots clés
- Avertissement

Astuce pour imprimer les couleurs des cellules de tableaux : http://www.gaudry.be/ast-rf-450.html

Aucun commentaire pour cette page

tection. Enregistrement IDDN n° 5329
Document créé le 11/06/04 03:45, dernière modification le Lundi 11 Janvier 2010, 17:01
Source du document imprimé : http://www.gaudry.be/vbs-diskinfo.html Document affiché 59 fois ce mois de Mars.
St.Gaudry©07.01.02